Always Using CALCULATE

One mistake I often see DAX users make is leaning on CALCULATE as their default function. The truth is, CALCULATE is only necessary when you need to apply or override a filter condition. If you’re simply aggregating data, the existing filter context on the report already does the work for you. Overusing CALCULATE not only clutters your measures but can also slow down processing, especially at scale. Use it only when it’s truly needed to keep your DAX efficient and easier to work with.

-- Total Sales for 2025 only

Total Sales 2025 =
CALCULATE (
    SUM ( Sales[Amount] ),
    YEAR ( Sales[Date] ) = 2025
)

CALCULATE is needed here because you’re overriding the filter context to restrict results to 2025.

-- Total Sales ignoring Product filters
Total Sales All Products =
CALCULATE (
    SUM ( Sales[Amount] ),
    ALL ( Product )
)

Here CALCULATE is essential because you’re removing the filter on Product. Without it, the measure would respect the current product context.

-- Total Sales
Total Sales =
CALCULATE ( SUM ( Sales[Amount] ) )

This adds no value. The existing filter context already applies, so SUM(Sales[Amount]) alone is cleaner and faster.

-- Total Sales combined
Total Sales =
CALCULATE ( [TotalSalesTable1] + [TotalSalesTable2] )

CALCULATE doesn’t add anything here. It just slows things down.

Clearing Date Filters That Aren’t There

Another mistake I often notice is using date-related criteria in measures when the report doesn’t actually have any date filters applied. For instance, writing something like:

Total Sales =
CALCULATE (
    SUM ( Sales[Amount] ),
    ALL ( Dates[Date] )
)

If there are no (and there will not be) date filters on the report, that ALL ( Dates[Date] ) is redundant. It doesn’t change the result, but it makes the measure slower and harder to follow. A simpler

Total Sales = SUM ( Sales[Amount] )

does the job just as well. Save the ALL() (or other date overrides) for situations where the report or visuals really do have date filters you want to ignore.

Always Writing in 1 Line

Cramming an entire measure into a single line might look tidy at first, but it quickly becomes unreadable and painful to debug. DAX is much easier to maintain when you use spaces, line breaks, indentation, and variables (VAR … RETURN) to structure your logic. Clean formatting makes it obvious what’s happening step by step, and it helps both you and anyone else who needs to read or update the code later.

Category = IF(SUM(Sales[Amount]) > 100000, "High", IF(SUM(Sales[Amount]) > 50000, "Medium", "Low"))

This running line of text can become out of control to read, especially if you didn’t write it yourself.

Category =
VAR TotalSales = SUM ( Sales[Amount] )
RETURN
    IF ( TotalSales > 100000,
        "High",
        IF ( TotalSales > 50000,
            "Medium",
            "Low"
        )
    )

Using variables for objects that are referenced multiple times improves both efficiency and readability.